自宅と職場でDHCPから固定IPアドレス+プロキシ設定を切り替えるツール

通常の使用時にはDHCPで運用することが一般的にはほとんどかと思いますが，職場等ではセキュリティ上，IPアドレスを固定し，またプロキシ設定をしなければならないことが多々あると思われます．

一方でこれらの設定はWindowsの場合，システムの設定から一々切り替えなければならず，非常に不便です．

バッチファイルを作成して，「DHCP」と「IPアドレス固定+プロキシ設定」をボタン一つで切り替えることのできる簡便なツールを作成してみました．

バッチファイルの作成
実際の使い方

バッチファイルの作成

@echo off
rem ///////////////////////////////////////////
rem
rem DHCPと固定IP+プロキシ設定切り替え
rem
rem ///////////////////////////////////////////

:menu

set NUM=
set IFNAME="Wi-Fi"
rem set IFNAME="ローカル エリア接続"


CLS
echo -------------------- MENU --------------------
echo [1] 固定IPへ変更＋プロキシ設定を有効化
echo [2] DHCPへ変更＋プロキシ設定を無効化
echo [3] 終了
echo ----------------------------------------------
echo.
set /p NUM="実行する処理の番号を入力 > "
if "%NUM%"=="1" goto ipproxy
if "%NUM%"=="2" goto dhcp
if "%NUM%"=="3" goto end
goto NoNumber

rem -------------------------------------------
:ipproxy

set IPADDR=*.*.*.*
set MASK=*.*.*.*
set GW=*.*.*.*
set DNS1=*.*.*.*
set DNS2=
set PROXYIPaddr=*.*.*.*
set PORT=*

echo %IFNAME% に %IPADDR% を設定しています。
netsh interface ipv4 set address name=%IFNAME% source=static address=%IPADDR% mask=%MASK% gateway=%GW%
netsh interface ipv4 set dns name=%IFNAME% source=static address=%DNS1% register=primary validate=no
echo.

echo プロキシ設定を有効化しています。
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings" /f /v ProxyEnable /t REG_DWORD /d 1
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings" /f /v ProxyServer /t REG_SZ /d %PROXYIPaddr%:%PORT%
rem reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings" /f /v ProxyOverride /t REG_SZ /d %IntraAddr%
rem inetcpl.cpl
ipconfig
echo.
echo 変更が完了しました。
pause
goto menu

rem -------------------------------------------
:dhcp

echo %IFNAME% に DHCP を設定しています。
netsh interface ipv4 set address name=%IFNAME% dhcp
netsh interface ipv4 set dnsservers name=%IFNAME% dhcp
echo.

echo プロキシ設定を無効化しています。
reg add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings" /f /v ProxyEnable /t REG_DWORD /d 0
rem inetcpl.cpl
ipconfig
echo.
echo 変更が完了しました。
pause
goto menu

rem -------------------------------------------
:NoNumber
echo 入力が誤っています。
echo.
pause
goto menu

rem -------------------------------------------
:end
exit

上記をメモ帳などに記載してマーカーでハイライトした，「set IPADDR=*.*.*.*，set MASK=*.*.*.*，set GW=*.*.*.*，set DNS1=*.*.*.*，set DNS2=，set PROXYIPaddr=*.*.*.*，set PORT=*」を自身の環境に沿って設定してください．

それぞれ固定したいIPアドレス，サブネットマスク，ゲートウェイ，DNS1と2，プロキシサーバーの設定となっています．

最後に*.batファイルとして保存してください．